|
最近公司網路不穩，順子常常使用指令ping來觀察網路品質。
為了長時間的觀察與分析ping值，
順子寫了一個看似簡單的ping值觀察批次檔。
使用者可以依需求修改批次檔中的ip，pingdir，與p-time參數。
其中ip為觀察的IP位址，
pingdir為輸出之ping值資料存放路徑，
p-time為ping每次探尋的次數。
@echo off & setLocal enableDELAYedexpansion
set ip=168.95.192.1
set pingdir=D:\ping\
set p-time=10
:start
ping -n %p-time% %ip% > %pingdir%%ip%.tmp
set N=
for /f "tokens=* delims= " %%a in (%pingdir%%ip%.tmp) do (
set /a N+=1
)
set /a X=!N!-4
set N=
for /f "tokens=* delims= " %%a in (%pingdir%%ip%.tmp) do (
set /a N+=1
if !N! gtr !X! (
echo %%a
set /a Y=!N! %% 2
if !Y! equ 0 (
echo %%a >> %pingdir%%ip%.short.txt
)
)
)
type %pingdir%%ip%.tmp >> %pingdir%%ip%.txt
echo %date% %time% >> %pingdir%%ip%.txt
echo %date% %time% >> %pingdir%%ip%.short.txt
echo. >> %pingdir%%ip%.short.txt
echo %date% %time%
echo.
goto start
此程式執行後，會在pingdir目錄下產生三個檔案，
分別為"觀察IP.txt"，"觀察IP.tmp"及"觀察IP.short.txt"。
其中"觀察IP.txt"為完整的ping值資料檔，
由於包含ping完整回傳之數值，此檔案會快速成長。
"觀察IP.tmp"則是一個單次ping後的暫存檔。
而"觀察IP.short.txt"則為精簡ping值回傳資訊，
僅留下封包傳送率與平均時間後的檔案。
有需要的朋友可以參考看看∼
♥順子老婆的網拍，請多關照∼
If you don't like something, change it.
If you can't change it, change your attitude.
Don't complain!
|
2010-03-17, 17:20
《分享》Ping值觀察程式
